module modbus.backend.rtu;

import std.experimental.logger;
import std.exception : enforce;
import std.bitmanip;

import modbus.exception;
import modbus.iface;
import modbus.protocol;

version (unittest) static this() { sharedLog = new NullLogger; }

class RTU : Modbus.Backend
{
    SerialPortIface com;
    ubyte[256] buffer;
    size_t idx;

    enum minimumMsgLength = 5;

public:

    this(SerialPortIface spi)
    {
        this.com = enforce(spi, "serial port is null");
    }

    override
    {
        void start(ubyte dev, ubyte func)
        {
            this.write(dev);
            this.write(func);
        }

        void append(byte v) { this.write(v); }
        void append(ubyte v) { this.write(v); }
        void append(short v) { this.write(v); }
        void append(ushort v) { this.write(v); }
        void append(int v) { this.write(v); }
        void append(uint v) { this.write(v); };
        void append(long v) { this.write(v); };
        void append(ulong v) { this.write(v); };
        void append(float v) { this.write(v); };
        void append(double v) { this.write(v); };

        void append(const(void)[] v)
        {
            auto inc = v.length;
            //                 CRC
            enforce(inc + idx + 2 < buffer.length, "many args");
            buffer[idx..idx+inc] = cast(ubyte[])v;
            idx += inc;
        };

        bool messageComplite() const @property { return idx == 0; }
        const(void)[] tempBuffer() const @property { return buffer[0..idx]; }

        void send()
        {
            scope (exit) idx = 0;
            append(cast(const(void)[])(crc16(buffer[0..idx])[]));
            com.write(buffer[0..idx]);
            .trace("write bytes: ", buffer[0..idx]);
        }

        Response read(size_t expectedBytes)
        {
            //              dev fnc CRC
            expectedBytes += 1 + 1 + 2;

            Response res;
            auto tmp = com.read(buffer[]);

            .trace(" read bytes: ", cast(ubyte[])tmp);

            enforce(tmp.length >= minimumMsgLength,
                new ReadDataLengthException(tmp.length < 1 ? 0 : (cast(ubyte[])tmp)[0],
                                            tmp.length < 2 ? 0 : (cast(ubyte[])tmp)[1],
                                            expectedBytes, tmp.length));

            if (tmp.length > expectedBytes)
            {
                .warningf("receive more bytes what expected (%d): %(0x%02x %)",
                            expectedBytes, cast(ubyte[])tmp[expectedBytes..$]);

                tmp = tmp[0..expectedBytes];
            }

            res.dev = (cast(ubyte[])tmp)[0];
            res.fnc = (cast(ubyte[])tmp)[1];

            enforce(checkCRC(tmp), new CheckCRCException(res.dev, res.fnc));

            res.data = tmp[2..$-2];

            return res;
        }
    }

protected:

    void write(T)(T v)
    {
        scope (failure) idx = 0;
        //                      CRC
        enforce(T.sizeof + idx + 2 < buffer.length, "many args");
        buffer[].write(v, &idx);
    }
}

unittest
{
    import std.algorithm;

    void[] buf;

    auto rtu = new RTU(new class SerialPortIface
            { override:
                void write(const(void)[] t) { buf = t.dup; }
                void[] read(void[] buffer)
                {
                    assert(buffer.length <= buf.length);
                    buffer[0..buf.length] = buf[];
                    return buffer[0..buf.length];
                }
            });

    enum C1 = ushort(10100);
    enum C2 = ushort(12345);
    rtu.start(1, 6);
    rtu.append(C1);
    rtu.append(C2);
    assert(!rtu.messageComplite);
    assert(rtu.tempBuffer.length == 2 + 2 + 2);
    rtu.send();
    assert(rtu.messageComplite);
    assert(rtu.tempBuffer.length == 0);
    assert(equal(cast(ubyte[])buf[0..$-2],
                cast(ubyte[])[1, 6] ~ nativeToBigEndian(C1) ~ nativeToBigEndian(C2)));

    auto crc = cast(ubyte[])crc16(buf[0..$-2]);
    assert(crc[0] == (cast(ubyte[])buf)[$-2]);
    assert(crc[1] == (cast(ubyte[])buf)[$-1]);
}

bool checkCRC(const(void)[] data)
{
    auto msg = cast(const(ubyte[]))data;
    auto a = msg[$-2..$];
    auto b = crc16(msg[0..$-2]);
    return a[0] == b[0] && a[1] == b[1];
}

unittest
{
    immutable ubyte[] data = [0x02, 0x03, 0x00, 0x00, 0x00, 0x05, 0x85, 0xFA];
    assert(checkCRC(data));
}

ubyte[2] crc16(const(void)[] data) pure nothrow @trusted
{

    ubyte hi = 0xFF;
    ubyte lo = 0xFF;

    size_t idx;

    foreach (val; cast(ubyte[])data)
    {
        idx = lo ^ val;
        lo = hi ^ tblHi[idx];
        hi = tblLo[idx];
    }

    return [lo, hi];
}

unittest
{
    immutable ubyte[] data = [0x02, 0x03, 0x00, 0x00, 0x00, 0x05];
    assert(crc16(data)[1] == 0xFA);
    assert(crc16(data)[0] == 0x85);
}

private:
enum ubyte[] tblHi = [
    0x00, 0xC1, 0x81, 0x40, 0x01, 0xC0, 0x80, 0x41, 0x01, 0xC0,
    0x80, 0x41, 0x00, 0xC1, 0x81, 0x40, 0x01, 0xC0, 0x80, 0x41,
    0x00, 0xC1, 0x81, 0x40, 0x00, 0xC1, 0x81, 0x40, 0x01, 0xC0,
    0x80, 0x41, 0x01, 0xC0, 0x80, 0x41, 0x00, 0xC1, 0x81, 0x40,
    0x00, 0xC1, 0x81, 0x40, 0x01, 0xC0, 0x80, 0x41, 0x00, 0xC1,
    0x81, 0x40, 0x01, 0xC0, 0x80, 0x41, 0x01, 0xC0, 0x80, 0x41,
    0x00, 0xC1, 0x81, 0x40, 0x01, 0xC0, 0x80, 0x41, 0x00, 0xC1,
    0x81, 0x40, 0x00, 0xC1, 0x81, 0x40, 0x01, 0xC0, 0x80, 0x41,
    0x00, 0xC1, 0x81, 0x40, 0x01, 0xC0, 0x80, 0x41, 0x01, 0xC0,
    0x80, 0x41, 0x00, 0xC1, 0x81, 0x40, 0x00, 0xC1, 0x81, 0x40,
    0x01, 0xC0, 0x80, 0x41, 0x01, 0xC0, 0x80, 0x41, 0x00, 0xC1,
    0x81, 0x40, 0x01, 0xC0, 0x80, 0x41, 0x00, 0xC1, 0x81, 0x40,
    0x00, 0xC1, 0x81, 0x40, 0x01, 0xC0, 0x80, 0x41, 0x01, 0xC0,
    0x80, 0x41, 0x00, 0xC1, 0x81, 0x40, 0x00, 0xC1, 0x81, 0x40,
    0x01, 0xC0, 0x80, 0x41, 0x00, 0xC1, 0x81, 0x40, 0x01, 0xC0,
    0x80, 0x41, 0x01, 0xC0, 0x80, 0x41, 0x00, 0xC1, 0x81, 0x40,
    0x00, 0xC1, 0x81, 0x40, 0x01, 0xC0, 0x80, 0x41, 0x01, 0xC0,
    0x80, 0x41, 0x00, 0xC1, 0x81, 0x40, 0x01, 0xC0, 0x80, 0x41,
    0x00, 0xC1, 0x81, 0x40, 0x00, 0xC1, 0x81, 0x40, 0x01, 0xC0,
    0x80, 0x41, 0x00, 0xC1, 0x81, 0x40, 0x01, 0xC0, 0x80, 0x41,
    0x01, 0xC0, 0x80, 0x41, 0x00, 0xC1, 0x81, 0x40, 0x01, 0xC0,
    0x80, 0x41, 0x00, 0xC1, 0x81, 0x40, 0x00, 0xC1, 0x81, 0x40,
    0x01, 0xC0, 0x80, 0x41, 0x01, 0xC0, 0x80, 0x41, 0x00, 0xC1,
    0x81, 0x40, 0x00, 0xC1, 0x81, 0x40, 0x01, 0xC0, 0x80, 0x41,
    0x00, 0xC1, 0x81, 0x40, 0x01, 0xC0, 0x80, 0x41, 0x01, 0xC0,
    0x80, 0x41, 0x00, 0xC1, 0x81, 0x40];

enum ubyte[] tblLo = [
    0x00, 0xC0, 0xC1, 0x01, 0xC3, 0x03, 0x02, 0xC2, 0xC6, 0x06,
    0x07, 0xC7, 0x05, 0xC5, 0xC4, 0x04, 0xCC, 0x0C, 0x0D, 0xCD,
    0x0F, 0xCF, 0xCE, 0x0E, 0x0A, 0xCA, 0xCB, 0x0B, 0xC9, 0x09,
    0x08, 0xC8, 0xD8, 0x18, 0x19, 0xD9, 0x1B, 0xDB, 0xDA, 0x1A,
    0x1E, 0xDE, 0xDF, 0x1F, 0xDD, 0x1D, 0x1C, 0xDC, 0x14, 0xD4,
    0xD5, 0x15, 0xD7, 0x17, 0x16, 0xD6, 0xD2, 0x12, 0x13, 0xD3,
    0x11, 0xD1, 0xD0, 0x10, 0xF0, 0x30, 0x31, 0xF1, 0x33, 0xF3,
    0xF2, 0x32, 0x36, 0xF6, 0xF7, 0x37, 0xF5, 0x35, 0x34, 0xF4,
    0x3C, 0xFC, 0xFD, 0x3D, 0xFF, 0x3F, 0x3E, 0xFE, 0xFA, 0x3A,
    0x3B, 0xFB, 0x39, 0xF9, 0xF8, 0x38, 0x28, 0xE8, 0xE9, 0x29,
    0xEB, 0x2B, 0x2A, 0xEA, 0xEE, 0x2E, 0x2F, 0xEF, 0x2D, 0xED,
    0xEC, 0x2C, 0xE4, 0x24, 0x25, 0xE5, 0x27, 0xE7, 0xE6, 0x26,
    0x22, 0xE2, 0xE3, 0x23, 0xE1, 0x21, 0x20, 0xE0, 0xA0, 0x60,
    0x61, 0xA1, 0x63, 0xA3, 0xA2, 0x62, 0x66, 0xA6, 0xA7, 0x67,
    0xA5, 0x65, 0x64, 0xA4, 0x6C, 0xAC, 0xAD, 0x6D, 0xAF, 0x6F,
    0x6E, 0xAE, 0xAA, 0x6A, 0x6B, 0xAB, 0x69, 0xA9, 0xA8, 0x68,
    0x78, 0xB8, 0xB9, 0x79, 0xBB, 0x7B, 0x7A, 0xBA, 0xBE, 0x7E,
    0x7F, 0xBF, 0x7D, 0xBD, 0xBC, 0x7C, 0xB4, 0x74, 0x75, 0xB5,
    0x77, 0xB7, 0xB6, 0x76, 0x72, 0xB2, 0xB3, 0x73, 0xB1, 0x71,
    0x70, 0xB0, 0x50, 0x90, 0x91, 0x51, 0x93, 0x53, 0x52, 0x92,
    0x96, 0x56, 0x57, 0x97, 0x55, 0x95, 0x94, 0x54, 0x9C, 0x5C,
    0x5D, 0x9D, 0x5F, 0x9F, 0x9E, 0x5E, 0x5A, 0x9A, 0x9B, 0x5B,
    0x99, 0x59, 0x58, 0x98, 0x88, 0x48, 0x49, 0x89, 0x4B, 0x8B,
    0x8A, 0x4A, 0x4E, 0x8E, 0x8F, 0x4F, 0x8D, 0x4D, 0x4C, 0x8C,
    0x44, 0x84, 0x85, 0x45, 0x87, 0x47, 0x46, 0x86, 0x82, 0x42,
    0x43, 0x83, 0x41, 0x81, 0x80, 0x40];